Access 2007 par l'exemple : Intégration d'images dans les Formulaires Continus

Date de publication : 24/07/2006 , Date de mise à jour : 10/01/2007

Par Morgan BILLY (Espace Perso de Dolphy35)

Dans le cadre de la découverte des nouvelles fonctionnalités d'Access12, nous allons parler dans cet article d'une nouveauté très attendue le rattachement d'un champ d'une table avec un cadre image.

Version PDF (Miroir)

I. Introduction
II. Principe
II-A. Le Formulaire 1
II-B. Le Formulaire 2
III. Techniques utilisées
IV. Structure de la base de données
V. L'interface graphique
V-A. Le Formulaire N°1
V-B. Le Formulaire N°2
VI. Ajout d'un dossier
VII. Code VBA
VII-A. Déclarations des Variables
VII-B. Boîte de dialogue Ouvrir
VII-C. Gestion de l'erreur en cas d'image non valide
VII-D. Extraction du nom du Fichier
VII-E. Copie de l'image sélectionnée et ajout dans la table
VII-F. Code Complet
VIII. Conclusion
IX. Remerciements
X. Me contacter

I. Introduction

Cette fonctionnalité très attendue depuis longtemps permet un rattachement d'un cadre image à un champ d'une table. Cette nouveauté va vous permettre entre autre d'afficher une image différente dans un cadre d'un formulaire en mode continu.

Nous allons aussi aborder également les objets FileDialog.

Ce tutoriel a été rédigé principalement pour vous faire découvrir des nouvelles fonctionnalités de la version d'Access 2007.

II. Principe

Cette base de données servant d'exemple au sein de ce tutoriel a pour objectif de découvrir la nouvelle mouture d'Access version 12.

Principe de fonctionnement :

Renseignement des champs de la fiche employés.
Ajout de la photo de l'employé en la sélectionnant à l'aide de la boîte de dialogue Ouvrir.
Copie de l'image sélectionnée dans un sous répertoire de la base courante, pour éviter de perdre les données lors d'un déplacement de la base, par exemple.

II-A. Le Formulaire 1

Il s'agit d'un formulaire de saisie d'employés (Nom, prénom, salaire, poste et photo). Ce formulaire se présente sous forme de fiche.

II-B. Le Formulaire 2

Ce formulaire permet également de saisir les employés (Nom, prénom, salaire, poste et photo). Toutefois et contrairement au précédent, il est en mode continu ce qui signifie qu'il affiche tous les enregistrements les uns en dessous des autres.

Et oui, vous ne rêvez pas, ce sont bien des images dans un formulaire continu!

III. Techniques utilisées

Plusieurs solutions techniques sont mises en oeuvre à travers cet exemple.

Les photos ne sont pas attachées à la base mais liées par le chemin d'accès qui lui, est stocké dans un champ de type texte dans la table source.
Le bouton Insérer Photo affiche la boîte de dialogue Ouvrir du système d'exploitation en utilisant un objet FileDialog.

IV. Structure de la base de données

Dans un premier temps nous allons créer l'unique table appelée tblEmployes :

Créez une nouvelle table en mode création et renseignez les noms de champs ainsi que leur type comme cela est indiqué sur l'image ci-dessus.

V. L'interface graphique

V-A. Le Formulaire N°1

Créez un nouveau formulaire :

Il vous suffit simplement d'ajouter les différents contrôles depuis la liste des champs. La source du formulaire est la table tblEmployes. Ne pas oublier le bouton Insérer photo.

Pour insérer le cadre destiné à contenir l'image, sélectionnez bien le bouton image comme indiquer sur la photo ci-dessous.

Boîte à outils Access 2007.

Maintenant il faut lier les contrôles aux champs de la table par la propriété Source (onglet données). Effectuez un clic droit sur les contrôles puis sélectionnez
Propriétés -> Onglet Données -> Source -> sélectionnez le champs correspondant.

Grande nouveauté d'Access 2007 :
Il est maintenant possible de lier un contrôle image à un champ de la table.
C'est ce que nous allons effectuer avec le contrôle image qui sera lié au champ Photos de la table tblEmployes

Propriétés du Formulaire :

Onglet Format :

Affichage par défaut => Formulaire Unique.
Affichage Sélecteur => Non

Onglet Données :

Source => tblEmployes

V-B. Le Formulaire N°2

Créez alors le second formulaire :

Faites un copier/coller du Formulaire 1 en modifiant ces paramètres.

Propriétés du Formulaire :

Onglet Format :

Affichage par défaut => Formulaire Continus.
Affichage Sélecteur => Non

Onglet Données :

Source => tblEmployes

VI. Ajout d'un dossier

Pour un bon fonctionnement de cette application, il vous faut créer un sous-dossier dans le répertoire courant de la base que vous nommerez images. C'est ici que seront placés tous les fichiers images.

VII. Code VBA

Cette application ne possède qu'une procédure VBA qui utilise FileDialog et File.
Christophe WARIN a développé le sujet dans son tutoriel

Les pièces jointes par l'exemple : nous n'allons pas reprendre ces explications mais simplement les compléter un peu.

Ce code va permettre d'afficher la boîte de dialogue Windows pour sélectionner la photo à insérer dans le cadre image. Ce qu'il faut que vous assimiliez, c'est que nous ne stockons pas l'image dans le champ de la table mais le chemin pour y accéder. Avant cela nous allons effectuer une copie de l'image sélectionnée dans le dossier images.

VII-A. Déclarations des Variables

Pour disposer de cette fonctionnalité vous devez sélectionner la référence

Microsoft Office xx.x Object Library

Nous allons utiliser 2 variables dans ce code, strFichier qui stockera le nom de l'image sélectionnée et oFD objet de type FileDialog qui est l'instance de la boîte de dialogue ouvrir.

'Déclaration des variables
Dim strFichier As String
Dim oFD As FileDialog

VII-B. Boîte de dialogue Ouvrir

Nous allons paramétrer l'objet FileDialog afin d'obtenir ce type de boîte :

Il s'agit d'une boite ouvrir elle sera donc obtenue par :

Set oFD = Application.FileDialog(msoFileDialogOpen)

- Ajout des filtres de la boîte, il est possible de mettre plusieurs extensions dans un même filtre en les séparant par " ; ".

With oFD
'Ajoute les filtres pour fichiers images et tous
	With .Filters
		.Clear
		.Add "Fichiers images", "*.jpg;*.jpeg;*.bmp;*.gif", 1
		.Add "Tous", "*.*", 2
	End With

- Le Titre.

.Title = "Insérer une image"

- Répertoire par défaut lors de l'ouverture. Dans cet exemple nous allons ouvrir la boîte dans Mes documents\Mes images de l'utilisateur connecté.

-> La variable d'environnement USERPROFILE retourne le chemin d'accès du répertoire spécifique de l'utilisateur:

C:\Documents and Settings\Dolphy35

.InitialFileName = Environ("USERPROFILE") & "\Mes documents\Mes images"

- Pour interdire la sélection multiple des fichiers, qui génèrerait automatiquement une erreur, il vous faut définir la propriété .AllowMultiSelect à False.

.AllowMultiSelect = False

- Grande nouveauté d'Access12, le paramétrage de l'affichage des fichiers dans la boîte de dialogue en une seule ligne, dans notre exemple nous allons forcer l'affichage en type Apperçu

.InitialView = msoFileDialogViewPreview

- Vous pouvez également mettre l'affichage dans la boîte en Miniatures

.InitialView = msoFileDialogViewThumbnail

- Personnalisation du bouton Ouvrir.

.ButtonName = "Insérer"

- Affichage de la boîte de dialogue.

If .Show Then

VII-C. Gestion de l'erreur en cas d'image non valide

Appel de la Gestion de l'erreurs.

On Error GoTo fini

Si le fichier chargé dans le contrôle n'est pas une image l'erreur 2220 est levée ce qui nous permet d'afficher un message personnalisé.
Pour les autres erreurs, nous afficherons simplement le N° d'erreur et sa description.

fini:
Select Case Err
	Case 2220
		MsgBox "L'importation du fichier ne s'est pas effectué normalement.", _
			vbCritical, "Erreur fichier Image"
	Case Else
		MsgBox Err.Number & Chr(13) & Err.Description
	End Select

Affichage dans le contrôle du fichier sélectionné et renvoie une erreur si ce n'est pas une image.

Me.Image1.Picture = .SelectedItems(1)

Si l'erreur n'est pas levée nous effaçons l'image que l'on vient de charger, ceci dans un but purement d'esthétique.

Me.Image1.Picture = ""

VII-D. Extraction du nom du Fichier

Extraction du nom du fichier sélectionné pour la copie.

strFichier = Mid(.SelectedItems(1), InStrRev(.SelectedItems(1), "\"))

VII-E. Copie de l'image sélectionnée et ajout dans la table

Copie de l'image sélectionnée dans le dossier images du répertoire courant de la base.

FileCopy .SelectedItems(1), CurrentProject.Path & "\images" & strFichier

Chargement du chemin de l'image du sous dossier dans le champ de la table.

Me.Photos = CurrentProject.Path & "\images" & strFichier

Rafraichissement du Formulaire.

Me.Refresh

VII-F. Code Complet

Voici le code complet à mettre dans l'événement sur clic du bouton Insérer.

Private Sub btnInserer_Click()
'Déclaration des variables
Dim strFichier As String
Dim oFD As FileDialog
'Paramètre la fenêtre Ouvrir
Set oFD = Application.FileDialog(msoFileDialogOpen)
With oFD
    'Ajoute les filtres pour fichiers images et tous
    With .Filters
        .Clear
        .Add "Fichiers images", "*.jpg;*.jpeg;*.bmp;*.gif", 1
        .Add "Tous", "*.*", 2
    End With
    'Renseignement du titre
    .Title = "Insérer une image"
    'Ouvre l'explorateur dans le fichier 'Mes documents' du User connecté.
    .InitialFileName = Environ("USERPROFILE") & "\Mes documents\Mes images"
    'Interdit la multi sélection
    .AllowMultiSelect = False
    'Permet de choisir le mode d'affichage dans l'explorateur (ici apperçu)
    .InitialView = msoFileDialogViewPreview
    'Permet de personnaliser le bouton.
    .ButtonName = "Insérer"
    'Affiche la fenêtre
    If .Show Then
        On Error GoTo fini  'gestion erreur pour control importation
        'Retourne un erreur si pas fichier image.
        Me.Image1.Picture = .SelectedItems(1)
        'Vide du cadre image.
        Me.Image1.Picture = ""
        'Extraction du nom du fichier à copier.
        strFichier = Mid(.SelectedItems(1), InStrRev(.SelectedItems(1), "\"))
        'Copie du fichier sélectionné vers le sous dossier de la base.
        FileCopy .SelectedItems(1), CurrentProject.Path & "\images" & strFichier
        'Chargement dans control du chemin de l'image (sous dossier base).
        Me.Photos = CurrentProject.Path & "\images" & strFichier
        'Rafraîchit le Formulaire.
        Me.Refresh
    End If
End With
Exit Sub
fini:
    Select Case Err
        Case 2220
            MsgBox "L'importation du fichier ne c'est pas effectué normalement.", _
                vbCritical, "Erreur fichier Image"
        Case Else
            MsgBox Err.Number & Chr(13) & Err.Description
    End Select
End Sub

VIII. Conclusion

Comme vous avez pu le constater, la gestion des images a été largement améliorée dans Access2007 avec la possibilité de mettre des images dans des formulaires continus.

Bases exemple du tutoriel

IX. Remerciements

Merci à Tofalu, FRED-G, et Arkham46 Nono40 pour son excellent outil.
A www.developpez.com pour leur hébergement.

X. Me contacter

Vous désirez me contacter pour une préstation sur un produit de la suite Office, je vous invite à me retrouver sur Dolphydev

Version PDF (Miroir)

Copyright © 2008 BILLY Morgan. Aucune reproduction, même partielle, ne peut être faite de ce site et de l'ensemble de son contenu : textes, documents, images, etc sans l'autorisation expresse de l'auteur. Sinon vous encourez selon la loi jusqu'à 3 ans de prison et jusqu'à 300 000 E de dommages et intérêts. Droits de diffusion permanents accordés à developpez LLC. Cette page est déposée à la SACD.